/* These two IF statements determine the length and width dimensions
IF EXISTS("d2")
   IF d1>=d2 
      LENGTH = d1 
      WIDTH = d2 
   ENDIF 
   IF d1<d2 
      LENGTH = d2
      WIDTH = d1 
   ENDIF
ELSE
   LENGTH = d1
   WIDTH = d1
ENDIF
/* the following nested IF statements compile the length dimension into the desired
/* format - number-fractional remainder. i.e 24.875 = 24-7/8
len_rem = LENGTH-FLOOR(LENGTH)
len_rem_frac = itos(floor(len_rem*64))+"/64"
IF MOD(FLOOR(len_rem*64),2)<1
   len_rem_frac=itos(floor(len_rem*32))+"/32"
      IF MOD(FLOOR(len_rem*32),2)<1
         len_rem_frac=itos(floor(len_rem*16))+"/16"
            IF MOD(FLOOR(len_rem*16),2)<1
               len_rem_frac=itos(floor(len_rem*8))+"/8"
                  IF MOD (FLOOR(len_rem*8),2)<1
                     len_rem_frac=itos(floor(len_rem*4))+"/4"
                        IF MOD(FLOOR(len_rem*4),2)<1
                           len_rem_frac=itos(floor(len_rem*2))+"/2"
                        ENDIF
                  ENDIF
            ENDIF
      ENDIF
ENDIF
/* If the length dimension is a whole number, the following IF statement converts it
/* to a string.  If there is a remainder, it compiles the integer and remainder
/* into a string
IF FLOOR(LENGTH) == LENGTH
   len_dim = itos(LENGTH)
ELSE
   len_dim = itos(floor(LENGTH)) +"-"+len_rem_frac
ENDIF

/* The following statements apply the same logic to the WIDTH dimension.
wid_rem = WIDTH-FLOOR(WIDTH)
wid_rem_frac = itos(floor(wid_rem*64))+"/64"

IF MOD(FLOOR(wid_rem*64),2)<1
   wid_rem_frac=itos(floor(wid_rem*32))+"/32"
      IF MOD(FLOOR(wid_rem*32),2)<1
         wid_rem_frac=itos(floor(wid_rem*16))+"/16"
            IF MOD(FLOOR(wid_rem*16),2)<1
               wid_rem_frac=itos(floor(wid_rem*8))+"/8"
                  IF MOD (FLOOR(wid_rem*8),2)<1
                     wid_rem_frac=itos(floor(wid_rem*4))+"/4"
                        IF MOD(FLOOR(wid_rem*4),2)<1
                           wid_rem_frac=itos(floor(wid_rem*2))+"/2"
                        ENDIF
                  ENDIF
            ENDIF
      ENDIF
ENDIF
IF FLOOR(WIDTH) == WIDTH
   wid_dim = itos(WIDTH)
ELSE
   wid_dim = itos(floor(WIDTH)) +"-"+wid_rem_frac
ENDIF

/* Here I'm leveraging the custom parameter "MF_MATERIAL" in order to apply
/* the desired format for the dimension that will appear in the BOM

/* This IF statement checks if the material is plywood i.e "3/8 PLY"
IF SEARCH(MF_MATERIAL,"PLY")==5
   DIMENSIONS = "("+EXTRACT(MF_MATERIAL,1,3)+")"+" X "+len_dim+" X "+wid_dim
   /*Example result is DIMENSIONS = (3/8) X 24-1/2 X 12-3/4
ENDIF

IF SEARCH(MF_MATERIAL,"PLY")==7
   DIMENSIONS = "("+EXTRACT(MF_MATERIAL,1,5)+")"+" X "+len_dim+" X "+wid_dim
   /*Example result is DIMENSIONS = (3/8) X 24-1/2 X 12-3/4
ENDIF

/* This IF statement checks if the material is lumber i.e "1X4"
IF EXTRACT(MF_MATERIAL,2,1)=="X"
   DIMENSIONS = "("+MF_MATERIAL+")"+" X "+len_dim
   /* Example result is DIMENSIONS = (1X4) X 43-1/4
   IF (MF_MATERIAL == "2X12" | MF_MATERIAL == "1X12") & WIDTH < 11.25
         DIMENSIONS = "("+MF_MATERIAL+")"+ " X " +len_dim+" X "+wid_dim+" (RIPPED)"
   ENDIF
   IF (MF_MATERIAL == "2X8" | MF_MATERIAL == "1X8") & WIDTH < 7.25
         DIMENSIONS = "("+MF_MATERIAL+")"+ " X " +len_dim+" X "+wid_dim+" (RIPPED)"
   ENDIF
   IF (MF_MATERIAL == "2X6" | MF_MATERIAL == "1X6") & WIDTH < 5.5
         DIMENSIONS = "("+MF_MATERIAL+")"+ " X " +len_dim+" X "+wid_dim+" (RIPPED)"
   ENDIF
   IF (MF_MATERIAL == "2X10" | MF_MATERIAL == "1X10") & WIDTH < 9.25
         DIMENSIONS = "("+MF_MATERIAL+")"+ " X " +len_dim+" X "+wid_dim+" (RIPPED)"
   ENDIF
   IF (MF_MATERIAL == "2X4" | MF_MATERIAL == "1X4") & WIDTH < 3.5
         DIMENSIONS = "("+MF_MATERIAL+")"+ " X " +len_dim+" X "+wid_dim+" (RIPPED)"
   ENDIF
ENDIF

/* This IF statement checks if the material is foam, with 1" thickness i.e "1''-White"
IF EXTRACT(MF_MATERIAL,1,3)=="1''"
   DIMENSIONS = "(1)"+" X "+len_dim+" X "+wid_dim
   /* Example result is DIMENSIONS = (1) X 24-1/2 X 16-3/4
ENDIF

/* This IF statement checks if the material is foam, with 2" thickness i.e "2''-White"
IF EXTRACT(MF_MATERIAL,1,3)=="2''"
   DIMENSIONS = "(2)"+" X "+len_dim+" X "+wid_dim
   /* Example result is DIMENSIONS = (2) X 24-1/2 X 16-3/4
ENDIF

IF EXTRACT(MF_MATERIAL,1,3)=="4''"
   DIMENSIONS = "(4)"+" X "+len_dim+" X "+wid_dim
   /* Example result is DIMENSIONS = (2) X 24-1/2 X 16-3/4
ENDIF

IF EXTRACT(MF_MATERIAL,1,3)=="6''"
   DIMENSIONS = "(6)"+" X "+len_dim+" X "+wid_dim
   /* Example result is DIMENSIONS = (2) X 24-1/2 X 16-3/4
ENDIF

IF MF_MATERIAL == "Not Selected" | MF_MATERIAL == "Stated"
	DIMENSIONS = "SELECT PART MATERIAL"
ENDIF