REDEF/ON    
                   
A=1;B=2;C=3;D=4;E=5;F=6;G=7;H=8;I=9;J=10;K=11;L=12;M=13;N=14
O=15;P=16;Q=17;R=18;S=19;T=20;U=21;V=22;W=23;X=24;Y=25;Z=26


$$ SET UP DUMMY DEFAULT FOR TOOL COMMENT
  TLTEXT=TEXT/'SEE INSTRUCTIONS FOR NEXT TOOL'
  CUTDIA=TEXT/'CUTTER_DIAM'          $$ SET UP A CONSTANT FOR PPRINTS
  COMMNT=TEXT/'COMMENT'              $$ SET UP A CONSTANT FOR PPRINTS

$$ SET UP ARRAY TO TRACK TOOL USAGE
  RESERV/TOF,50
  DO/S10,N=1,50
     TOF(N)=0
  S10) CONTIN
  

$$ ****************************************************
$$ *        M A C H I N     S e c t i o n s           *
$$ **************************************************** 

CIMFIL/ON,MACHIN
  DMY=POSTF(13)     $$ Process

$$ OPEN AND START THE TOOL LIST FILE
INCLUD/TLOPEN.INC

CIMFIL/OFF


$$ ********************************************************************
$$ *        L O A D T L     S e c t i o n s                           *
$$ ******************************************************************** 

CIMFIL/ON,LOADTL
  DMY=POSTF(20)                                            
  TULNUM=POSTF(7,4)
  STLNUM=TEXT/CONVI,TULNUM,4        $$ CONVERT TULNUM TO STRING
  IF( TULNUM .EQ. 99 ) THEN
    MANNUM=POSTF(7,6)               $$ GETS OSETNO VALUE FOR TOOL NUMBER LOAD
    STLNUM=TEXT/CONVI,MANNUM,4      $$ CONVERT MANNUM TO STRING
    INSERT/' G00 G40 G49 G90$'      $$ IS THIS LINE NEEDED???
    INSERT/' G53 Z0.0$'             $$ BACK UP CHANGER ALL THE WAY
    STOP
    INSERT/'(MSG,  MANUALLY LOAD TOOL NUMBER' ,MANNUM,'  )$' 
      $$ DOES NOT OUTPUT "T01 M06". PROMPTS FOR MANUAL LOADING TOOL  
    DMY = POSTF(2,1,1867,1)         $$ TURN SIMULATION ON
    DMY = POSTF(21)
    DMY = POSTF(13)                 $$ DO WHAT G-POST CAN WITH A LOADTL
    DMY = POSTF(2,1,1867,0)         $$ TURN SIMULATION OFF
  ELSE 
    STOP
    INSERT/'(MSG,  LOADING TOOL NUMBER' ,TULNUM,'  )$'                                                  
$$ OUTPUT THE TOOL COMMENT TO THE TAPE IMAGE
    PPRINT/TLTEXT
    DMY=POSTF(21)                   $$ RETREIVE RECORD
$$ Add offset number if not programmed
    NBEL=POSTF(5)                   $$ Number of words
    IF (NBEL.EQ.4) THEN
$$ Only the tool number has been programmed
$$ Add OSETNO, Offset number=tool
      DMY=POSTF(9,5,(ICODEF(OSETNO)))
      DMY=POSTF(10,6,(POSTF(7,4)))
$$ Increase number of word
      DMY=POSTF(12,6)
    ENDIF
  TLOFF = POSTF(7,6)                $$ SAVE THE 'H' VALUE
$$ OUTPUT THE INFO TO THE TOOL LIST FILE
  IF(TOF(TLOFF) .EQ. 0 ) THEN       $$ THIS TOOL HASN'T BEEN OUTPUT YET
    STLOFF=TEXT/CONVI,TLOFF,3
    TTT=TEXT/STLNUM,'     ',STLOFF,'    ',CDTEXT,'     ',TLTEXT
    DMY=FILEF(1,1,TTT)
    TOF(TLOFF) = 1                   $$ SET FLAG FOR THIS TOOL
  ENDIF
  DMY=POSTF(13)                      $$ Process record
  ENDIF 
CIMFIL/OFF

$$ ******************************************************
$$ *              F I N I     S e c t i o n             *
$$ ****************************************************** 
CIMFIL/ON,FINI 
  JHD = POSTF(20)

$$ CLOSE THE TOOL LIST FILE
  IF(TULFIL.EQ.0)THEN                 $$ THE FILE IS OPEN
     T1=TEXT/'************************************'
     DMY=FILEF(1,1,T1)                $$ WRITE A LINE TO THE FILE
     DMY=FILEF(1,5)                   $$ CLOSE THE FILE
  ENDIF

  DMY=POSTF(21)       $$ recall saved record
  DMY=POSTF(13)       $$ Process the record
CIMFIL/OFF
$$*********************************************************************
FINI