PRO_TK_E_NOT_FOUND will be returned if the call was successfully but no data was found.
SOLID, I would say a solid is everything where the Creo file extension is either '.PRT' (model type PRO_PART) or '.ASM' (model type PRO_ASSEMBLY)
Tcl Code less than 30 lines (in a colored image, after that clear uncolored code) follows, C logic is very similar > 30 lines 😀, even if you use your own filter function
# Side effects
# Each component is checked
# and the point data is not transformed
# to the top level assembly
#
# Function Input:
# FP : The handle to the open file
# MDL : The Name of the Solid Model
# Pat : The pattern to match, e.g A* match ACSYS
proc Get_Csys_Match {FP MDL PAT} {
foreach GEOM_ID [ps_visit csys -model $MDL] {
# Get the Feature ID for this geom id
set FEAT_ID [ps_geom to_feat_ids -model $MDL -- CSYS $GEOM_ID]
# Get the Feature Name
set FEAT_NAME [ps_feat name -model $MDL -- $FEAT_ID]
# Now the Match check
# Here do a match of the csys name by the given pattern
# if not match, continue
if {![string match -nocase $PAT $FEAT_NAME]} {
continue
}
# Prepare the Output
set Record [list $MDL $FEAT_NAME]
# Get the Csys Data to an csysObj
ps_data csys -model $MDL -- $GEOM_ID CsysData
# extract each vector, skip origin and other data
foreach vector [list xvector yvector zvector origin] {
# from the csysObj extract the 3D point data to an pointObj
CsysData $vector Point
# lappend the 3D Values by expanding to the output record list
lappend Record {*}[Point 3d_values]
}
# write the data in our file, use ',' as an seperator
puts $FP [join $Record ,]
}
}
# Function Input:
# FP : The handle to the open file
# ASM : The Name of the Assembly
# Pat : The pattern to match, e.g A* match ACSYS
proc Get_Assy_Csys_Match {FP ASM PAT} {
# Get it for the assembyl as well
Get_Csys_Match $FP $ASM $PAT
# Vist the given assembly, get all feature IDs
# where the feature type is a component
foreach FID [ps_visit type -model $ASM -- COMPONENT] {
# Get the model name from this feature ID
set MDL [ps_assy component_name -model $ASM -- $FID ]
# Now get all Geom ID from each CSYS in this Solid
# No filter for sub types like skeleton, ...
Get_Csys_Match $FP $MDL $PAT
# Recursive Call
# If the model is an assembly,
# search in this assembly as well
if { [ps_model is_assembly -model $MDL]} {
Get_Assy_Csys_Match $FP $MDL $PAT
}
}
# Done and return
return
}
proc CSYS_Test {} {
# The Pattern to search for
set PAT A*
# use the current active Model
set MODEL [ps_model cur]
# Prepare the filename
set outname [format "%s_csys_data.csv" $MODEL]
# open the file
set FP [open $outname w]
# write the header, use ',' as an seperator
puts $FP [join [list Model CsysName xvecx xvecy xvecz yvecx yvecy yvecz zvecx zvecy zvecz ovecx ovecy ovecz] ,]
# get the data
Get_Assy_Csys_Match $FP $MODEL $PAT
# close the file
close $FP
# Done and return
return
}
# just call it
CSYS_Test
Sample Out
Have fun 😇
