How to export text using the callout tool as .cgm

We had a macro created to export so we could have the error message turned off. Thanks to all who help with the creation of the macro.

This is the macro that we use to create a cgm and place it in the user pictures folder. You will need to create a temp folder on your c drive. It also creates a jpg of the illustration and places it in a networked drive folder labeled photos.

Macro export CGM to User Pictures folder
#Define variables.
Define JPGLocal as string
Define CGMLocal as string
Define fileName as string
Define CMDLocal as string
Define tempLocal as string
Define tempCGM as string

#Define cmd.exe.
CMDLocal = "C:\WINDOWS\system32\cmd.exe"

#Define local temp Local.
tempLocal = "C:\temp\"

#Turn off possible error/warning prompts during export.
app.interaction=false

#Save file to current Local.
Save

#Define variable for file name
fileName = stripext(activedoc.name)

#Set export Local for jpg.
JPGLocal="X:\Photos\" + fileName + ".jpg"

#Export jpg.
Export JPGLocal "JPEG"

#Set temp CGM export path.
tempCGM = tempLocal + filename + ".cgm"

#Set final cgm Local using cmd format (%variables%).
CGMLocal = "%userprofile%\pictures\" + stripext(activedoc.name) + ".cgm"

#Export CGM to temporary location.
Export tempCGM "CGM"

#Calls a cmd window and runs a move command to move the file to the final location.
Launch CMDLocal "/c move /Y " + tempCGM + " " + CGMLocal

#Turns prompts on.
app.interaction=true
End Macro